# Maintainer: Yamada Hayao <hayao@fascode.net>

pkgname=win12os-kde-git
_pkgname=win12os-kde
_gitname=Win12OS-kde
pkgver=r3.9951565
pkgrel=1
pkgdesc="Win12OS kde is a materia Design theme for KDE Plasma desktop"
arch=('any')
url='https://github.com/yeyushengfan258/Win12OS-kde'
license=('GPL')
depends=()
optdepends=()
source=("git+${url}.git")
md5sums=('SKIP')
conflicts=('win12os-kde')

pkgver() {
    cd "${_gitname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
    install -dm755 "${pkgdir}/usr/share/Kvantum/"
    install -dm755 "${pkgdir}/usr/share/aurorae/themes/"
    install -dm755 "${pkgdir}/usr/share/color-schemes/"
    install -dm755 "${pkgdir}/usr/share/plasma/desktoptheme/"
    install -dm755 "${pkgdir}/usr/share/plasma/layout-templates"
    install -dm755 "${pkgdir}/usr/share/plasma/look-and-feel/"
    install -dm755 "${pkgdir}/usr/share/wallpapers/"

    find "${srcdir}/${_gitname}" -type f -exec chmod 644 {} \;

    cp -r "${srcdir}/${_gitname}/Kvantum/"*              "${pkgdir}/usr/share/Kvantum/"
    cp -r "${srcdir}/${_gitname}/aurorae/"*              "${pkgdir}/usr/share/aurorae/themes/"
    cp -r "${srcdir}/${_gitname}/color-schemes/"*.colors "${pkgdir}/usr/share/color-schemes/"
    cp -r "${srcdir}/${_gitname}/plasma/desktoptheme/"*  "${pkgdir}/usr/share/plasma/desktoptheme/"
    cp -r "${srcdir}/${_gitname}/plasma/look-and-feel/"* "${pkgdir}/usr/share/plasma/look-and-feel/"
    cp -r "${srcdir}/${_gitname}/wallpaper/"*            "${pkgdir}/usr/share/wallpapers/"
}